< Establishing the object category form three independent keys. Test data - geometric figures. The first key will be used first. Please note that object Hexagon is missing in this key, but the system recognises it because it is included in other keys. >

"Using description table: http://members.xoom.com/AudriusA/es.htm " :
< This key will be used first. >
< http:// address will be opened after pressing the button "Connect" >
?[ALL] 'Four corners ' [Rectangle+Rhombus+Square+Irregular_Quadrilateral+Parallelogram]
'Other number of corners or no cornes $Circle' < Also presents the image from file Cirle.jpg > [Circle+Ellipse+Triangle+Hexagon];

?[ALL] 'Some corners $Square' [ALL-Ellipse-Circle]
'No corners $Figs/Ellipse' [Ellipse+Circle];

?[ALL] 'Two axes of symetric $Ellipse' [Rectangle+Rhombus+Ellipse]
'Other number of symetric axes $Circle' [ALL-Rectangle-Rhombus-Ellipse];

?[ALL] ' Figure is a closed curve, every point of which is equidistant from a given fixed point, the centre $Circle '[Circle]
' This geometric definition of circle is not correct for the object. ' [ALL - Circle];

?[Circle, Ellipse ] < Rule to distinguish between Circle and Ellipse... >
' Two axes of symmetric $Ellipse ' [ Ellipse ]
' Endless number of symmetric axes $Circle' [ Circle ];

?[ALL - Circle - Ellipse]
< Rule to recognise triangle or quadrilateral between polygons: >
' Three angles and three sides $Triangle ' [ Triangle ]
' Four angles $Rhombus' [ VISI - Circle - Ellipse - Triangle ];
<This table is sufficient to determine figures. However additional keys provides
possibility to reach conclusion if some questions have not been answered. >

"The first dichotomic key: http://members.xoom.com/AudriusA/es.htm" :

< The key, based on symmetric axes. "Connect" button connects to the given Internet page. . >

{ Figures:

1 ' No any symmetric axes $asymetr' 10 < Also presents the image from file asymetr.jpg >

' At least one symmetric axis $Spunge ' 2 ;

2 ' At least four symmetric axes $Square ' 24

' Some symmetric axes, but less than four $Rectangle ' 25 ;

10 ' At least two sides parallel. Parallelogram. $Paralel ' - Parallelogram

' No parallel sides. Irregular quadrilateral figure. $Irre '- Irregular_Quadrilateral;

24 ' Exactly four angles. $Rectangle. ' 31

' Other number of angles, including case with no angles $Triangle ' 32;

31 ' All four sides equal. Square. $Square ' - Square

' Some sides are not equal. Rectangle. $Rectangle. ' - Rectangle;

32 ' No angles. Circle. $Circle ' - Circle

' More than four angles. Hexagon. $Hexagon ' - Hexagon;

25 ' Three axes of symmetric. Triangle. $Triangle ' - Triangle

' Two axes of symmetric. $Rectangle ' 26;

26 ' Four angles. $Rectangle ' 27

' No angles. Ellipse. $Ellipse ' - Ellipse;

27 ' All sides are equal. Rhombus. $Rhombus ' - Rhombus

' Not all sides equal. Trapezium. $Trapezium ' - Trapezium;

}

< Next key begins here >

" The next key . Audrius.Meskauskas@fm.vtu.l t" 10:
< "Connect" button now opens E-mail window">

{ Figures:

1 ' The Object has four corners $Irre ' Quadrilateral

' The object has other number of corners or does not has them at all $Helix' 2;

2 ' The object has no corners $Orion ' Angleless

' Clear corners can be seen $Triangle ' 3;

3 ' Three corners. Triangle. $Triangle ' - Triangle

' Six corners. Hexagon. $Hexagon ' - Hexagon;

}

{ Quadrilateral:

1 ' At least two sides are parallel $Rectangle ' 2

' No parallel sides '- Irregular_Quadrilateral ;

2 ' More than for parallel sides' 3

' Only two parallel sides. Trapezium. $Trapezium '- Trapezium 24;

3 ' All sides are equal $Square ' 10

' Only opposite sides are equal $Rectangle '11 ;

10 ' All four angle are right (90 deg). Square. $Square ' - Square

' No any right angles. Rhombus. $Rhombus ' - Rhombus 26;

11 ' All four angle are right (90 deg). Rectangle. $Rectangle ' - Rectangle

' At least one angle is not right. Parallelogram. $Paralel ' - Parallelogram;

}

{ Angleless:

1 ' Object has the unlimited number of symmetric axes. Circle. $Circle ' - Circle

' Two symmetric axes. Ellipse. $Ellipse ' - Ellipse;

}

"The third key is now used":

{ Figures:

1 ' Three ore no any axes of symmetric $Horse ' Group_A

' Two or more than four axes of symmetric $Symetr' Group_B;

}

{ Group_B:

1 ' Height and width are equal ' Balanced

' Height is not equal to width ' Stretched;

}

{ Group_A:

1 ' Three equal sides. Triangle. $Triangle ' - Triangle

' Four not equal sides. Irregular quadrilateral figure. $Irre '- Irregular_Quadrilateral;

}

{ Balanced:

1 ' More than three corners ' 2

' No corners at all. Circle. $Circle ' - Circle;

2 ' Four equal sides ' 3

' Six equal sides. Hexagon. $Hexagon ' - Hexagon;

3 ' Right angles. Square. $Square ' - Square

' Angles not right. Rhombus. $Rhombus ' - Rhombus;

}

{ Stretched:

1 ' Four angles. Two sides parallel. ' 2

' No any angles. Ellipse. $Ellipse ' - Ellipse;

2 ' All angles right ' - Rectangle

' At least one angle is not right ' 3;

3 ' One axis of symmetric. Trapezium. $Trapezium ' - Trapezium

' No symmetric axes. Parallelogram. $Paralel ' - Parallelogram;

}

<Some direct rules can also be included>

?[ALL] ' Figure is a closed curve, every point of which is equidistant from a given fixed point, the centre '[ Circle]

' This geometric definition of circle is not correct for the object. '[ALL - Circle];

" Using fourth, rules-based key " 3:

?[Circle, Ellipse ]

< Rule to distinguish between Circle and Ellipse... >

' Two axes of symmetric ' [ Ellipse ]

' Endless number of symmetric axes ' [ Circle ];

?[VISI - Circle - Ellipse]

< Rule to recognise triangle or quadrilateral between polygons: >

' Three angles and three sides $Triangle ' [ Triangle ]

' Four angles ' [ ALL - Circle - Ellipse - Triangle ];

"Using final description database http://Figures.total.com "

?[Triangle] ' This is a final point. It was concluded that your figure is a triangle or something very simillar to it. You are now seing more detailed text from final points rule set. The yes/no layout is activated. $Figs/Triangle ' ;

?[Circle] ' This is a final point. It was concluded that your figure is a circle or something very simillar to it. You are now seing more detailed text from final points rule set. $Figs/Circle ';

< ...and so on. >

< End of file. Please note that you must recompile .key file after modification to update the corresponding .ts file. Also, the keys, written for older versions of Det, will be understood by newer versions, but obviously not other way round. To use all features, you can always download the updated version of Det from the main page.>

Back to main page.